{
  description = "Evie's machine configurations";

  inputs = {
    nixpkgs.url = "github:NixOS/nixpkgs/nixos-unstable";
    home-manager = {
      url = "github:nix-community/home-manager";
      inputs.nixpkgs.follows = "nixpkgs";
    };
    hyprland = {
      url = "github:hyprwm/Hyprland";
      inputs.nixpkgs.follows = "nixpkgs";
    };
    wallpapers.url = "git+https://git.xenia.me.uk/xenia/wallpapers.git";
    neovim-nightly-overlay = {
      url = "github:nix-community/neovim-nightly-overlay";
      inputs.nixpkgs.follows = "nixpkgs";
    };
  };

  outputs = {
    nixpkgs,
    home-manager,
    hyprland,
    wallpapers,
    neovim-nightly-overlay,
    ...
  }: let
    home-config = {
      imports = [home-manager.nixosModules.home-manager];
      home-manager = {
        useGlobalPkgs = true;
        useUserPackages = false;
        users.root = {
          imports = [./home/env/bash.nix ./home/env/starship.nix];
          home = {
            username = "root";
            homeDirectory = "/root";
            stateVersion = "22.11";
          };
        };
      };
    };
    xfce-bspwm-config = {pkgs, ...}: {
      environment.systemPackages = with pkgs; [
        nitrogen
        power-profiles-daemon
        xfce.thunar
        flameshot
        polybar
        ranger
      ];
      services.xserver = {
        enable = true;
        layout = "gb";
        xkbVariant = "";
        desktopManager = {
          xterm.enable = false;
          xfce = {
            enable = true;
            enableXfwm = false;
            noDesktop = true;
          };
        };
        windowManager.bspwm.enable = true;
        displayManager = {
          sddm = {
            enable = true;
            # theme = "catppuccin-macchiato";
            settings = {General = {InputMethod = "";};};
          };
          defaultSession = "xfce+bspwm";
          sessionCommands = ''
            ${pkgs.nitrogen}/bin/nitrogen --set-auto ${wallpapers.outputs.default}
          '';
        };
      };
      programs.i3lock = {
        enable = true;
        package = pkgs.i3lock-fancy;
      };
    };
  in {
    nixosConfigurations = {
      Legion = nixpkgs.lib.nixosSystem {
        pkgs = import nixpkgs {
          system = "x86_64-linux";
          config.allowUnfree = true;
        };
        modules = [
          home-config
          ./hosts/Legion
          ./services/Legion.nix
          {
            home-manager.users.xenia = {
              imports = [./home/personal.nix];
              home = {
                username = "xenia";
                homeDirectory = "/home/xenia";
                stateVersion = "22.11";
              };
            };
          }
        ];
      };
      Vanguard = nixpkgs.lib.nixosSystem {
        pkgs = import nixpkgs {
          system = "x86_64-linux";
          config.allowUnfree = true;
          overlays = [neovim-nightly-overlay.overlay];
        };
        modules = [
          home-config
          xfce-bspwm-config
          ./hosts/Vanguard
          ./services/sshd
          ./services/syncthing/Vanguard.nix
          ({pkgs, ...}: {
            services.xserver.displayManager.autologin.user = "xenia";
            hardware.steam-hardware.enable = true;
            programs = {
              xwayland.enable = true;
              gamescope = {
                enable = true;
                capSysNice = true;
              };
              steam = {
                enable = true;
                remotePlay.openFirewall = true;
                gamescopeSession.enable = true;
              };
            };
            home-manager.users.xenia = {
              imports = [
                ./home/personal.nix
                ./home/desktop/bspwm.nix
                ./home/gui
              ];
              home = {
                username = "xenia";
                homeDirectory = "/home/xenia";
                stateVersion = "22.11";
              };
              programs.neovim.package = pkgs.neovim-nightly;
            };
          })
        ];
      };
      Ronin = nixpkgs.lib.nixosSystem {
        pkgs = import nixpkgs {
          system = "x86_64-linux";
          config.allowUnfree = true;
          overlays = [neovim-nightly-overlay.overlay];
        };
        modules = [
          home-config
          xfce-bspwm-config
          ./hosts/Ronin
          ./services/syncthing/Ronin.nix
          ({pkgs, ...}: {
            services.xserver.displayManager.autologin.user = "elitherl";
            home-manager.users.elitherl = {
              imports = [
                ./home/work.nix
                ./home/desktop/bspwm.nix
                ./home/gui
              ];
              home = {
                username = "elitherl";
                homeDirectory = "/home/elitherl";
                stateVersion = "22.11";
              };
              programs.neovim.package = pkgs.neovim-nightly;
            };
          })
        ];
      };
    };
    homeConfigurations = {
      "tux@Monarch" = home-manager.lib.homeManagerConfiguration {
        pkgs = nixpkgs.legacyPackages."aarch64-darwin";
        modules = [
          ({pkgs, ...}: {
            imports = [./home/personal.nix ./home/gui/wezterm.nix];
            home = {
              username = "tux";
              homeDirectory = "/Users/tux";
              stateVersion = "23.05";
              packages = [pkgs.gcc];
            };
            programs = {
              home-manager.enable = true;
              zsh = {
                sessionVariables.CC = "${pkgs.gcc}/bin/gcc";
                envExtra = ''
                  eval "$(/opt/homebrew/bin/brew shellenv)"
                '';
              };
            };
            services.syncthing.enable = true;
          })
        ];
      };
      "xenia@Northstar" = home-manager.lib.homeManagerConfiguration {
        pkgs = nixpkgs.legacyPackages."aarch64-linux";
        modules = [
          {
            imports = [./home/personal.nix];
            home = {
              username = "xenia";
              homeDirectory = "/home/xenia";
              stateVersion = "22.11";
            };
            programs = {
              home-manager.enable = true;
              bash.bashrcExtra = ''
                source $HOME/.nix-profile/etc/profile.d/nix.sh
              '';
            };
            services.syncthing.enable = true;
            fonts.fontconfig.enable = true;
          }
        ];
      };
    };
  };
}