{
  description = "Evie's machine configurations";

  inputs = {
    nixpkgs.url = "github:NixOS/nixpkgs/nixos-unstable";
    home-manager = {
      url = "github:nix-community/home-manager";
      inputs.nixpkgs.follows = "nixpkgs";
    };
    wallpapers.url = "git+https://git.xenia.me.uk/xenia/wallpapers.git";
    neovim-nightly-overlay = {
      url = "github:nix-community/neovim-nightly-overlay";
      inputs.nixpkgs.follows = "nixpkgs";
    };
    hyprland.url = "github:hyprwm/Hyprland";
  };

  outputs = {
    nixpkgs,
    home-manager,
    wallpapers,
    neovim-nightly-overlay,
    hyprland,
    ...
  }: let
    home-manager-config = {
      imports = [home-manager.nixosModules.home-manager];
      home-manager = {
        useGlobalPkgs = true;
        useUserPackages = false;
        users.root = {
          imports = [./home/env/bash.nix ./home/env/starship.nix];
          home = {
            username = "root";
            homeDirectory = "/root";
            stateVersion = "22.11";
          };
        };
      };
    };
    services = {pkgs, ...}: {
      environment.systemPackages = with pkgs; [
        gsettings-desktop-schemas
        pavucontrol
        pamixer
        pulseaudio
        grim
        slurp
      ];
      security.pam.services.swaylock = {};
      programs.thunar = {
        enable = true;
        plugins = with pkgs.xfce; [
          thunar-archive-plugin
          thunar-volman
        ];
      };
      services = {
        blueman.enable = true;
        gvfs.enable = true;
        tumbler.enable = true;
      };
    };
    chromium = {
      programs.chromium = {
        enable = true;
        extensions = [
          "cjpalhdlnbpafiamejdnhcphjbkeiagm" # uBlock Origin
          "fnaicdffflnofjppbagibeoednhnbjhg" # Floccus
          "nngceckbapebfimnlniiiahkandclblb" # Bitwarden
          "dphilobhebphkdjbpfohgikllaljmgbn" # Simplelogin
        ];
        extraOpts = {
          "BrowserSignin" = 0;
          "SyncDisabled" = true;
          "PasswordManagerEnabled" = false;
          "SpellcheckEnabled" = true;
          "SpellcheckLanguage" = ["en-GB"];
        };
        defaultSearchProviderSearchURL = "https://duckduckgo.com/?q={searchTerms}";
        defaultSearchProviderEnabled = true;
      };
    };
    waybar-experimental-overlay = final: prev: {
      waybar = prev.waybar.overrideAttrs (oldAttrs: {
        mesonFlags = oldAttrs.mesonFlags ++ ["-Dexperimental=true"];
      });
    };
  in {
    nixosConfigurations = {
      Legion = nixpkgs.lib.nixosSystem {
        pkgs = import nixpkgs {
          system = "x86_64-linux";
          config.allowUnfree = true;
        };
        modules = [
          home-manager-config
          ./hosts/Legion
          ./services/Legion.nix
          {
            home-manager.users.xenia = {
              imports = [./home/personal.nix];
              home = {
                username = "xenia";
                homeDirectory = "/home/xenia";
                stateVersion = "22.11";
              };
            };
          }
        ];
      };
      Vanguard = nixpkgs.lib.nixosSystem {
        pkgs = import nixpkgs {
          system = "x86_64-linux";
          config.allowUnfree = true;
          overlays = [
            waybar-experimental-overlay
            neovim-nightly-overlay.overlay
          ];
        };
        modules = [
          home-manager-config
          services
          chromium
          hyprland.nixosModules.default
          ./hosts/Vanguard
          ./services/sshd
          ./services/syncthing/Vanguard.nix
          ({pkgs, ...}: {
            hardware.steam-hardware.enable = true;
            programs = {
              xwayland.enable = true;
              hyprland.enable = true;
              gamescope = {
                enable = true;
                capSysNice = true;
              };
              steam = {
                enable = true;
                remotePlay.openFirewall = true;
                gamescopeSession.enable = true;
              };
            };
            home-manager.users.xenia = {
              imports = [
                hyprland.homeManagerModules.default
                ./home/personal.nix
                ./home/desktop/hyprland
                ./home/desktop/waybar/main.nix
                ./home/gui
              ];
              home = {
                username = "xenia";
                homeDirectory = "/home/xenia";
                stateVersion = "22.11";
              };
              programs.neovim.package = pkgs.neovim-nightly;
              xdg.configFile."hypr/hyprpaper.conf".text = ''
                preload = ${wallpapers.outputs.default}
                wallpaper = ,${wallpapers.outputs.default}
              '';
              xdg.configFile."hypr/display.conf".text = ''
                monitor=DP-1,highrr,auto,1
                monitor=DP-2,highrr,auto,1
                monitor=HDMI-1,highres,auto,2
                monitor=HDMI-2,highres,auto,2
                monitor=,preferred,auto,auto
                exec-once=gamescope -w 1920 -h 1080 -W 3840 -H 2160 -U -f --hdr-enabled -e -- steam -gamepadui
              '';
            };
          })
        ];
      };
      Ronin = nixpkgs.lib.nixosSystem {
        pkgs = import nixpkgs {
          system = "x86_64-linux";
          config.allowUnfree = true;
          overlays = [
            waybar-experimental-overlay
            neovim-nightly-overlay.overlay
          ];
        };
        modules = [
          home-manager-config
          services
          chromium
          hyprland.nixosModules.default
          ./hosts/Ronin
          ./services/syncthing/Ronin.nix
          ({pkgs, ...}: {
            programs.hyprland.enable = true;
            home-manager.users.elitherl = {
              imports = [
                hyprland.homeManagerModules.default
                ./home/work.nix
                ./home/desktop/hyprland
                ./home/desktop/waybar/main.nix
                ./home/desktop/waybar/laptop.nix
                ./home/gui
              ];
              home = {
                username = "elitherl";
                homeDirectory = "/home/elitherl";
                stateVersion = "22.11";
              };
              programs.neovim.package = pkgs.neovim-nightly;
              programs.waybar.settings = {
                main."output" = "DP-5";
                compact."output" = ["eDP-1" "DP-3"];
              };
              xdg.configFile."hypr/hyprpaper.conf".text = ''
                preload = ${wallpapers.outputs.default}
                wallpaper = ,${wallpapers.outputs.default}
              '';
              xdg.configFile."hypr/display.conf".text = ''
                monitor=desc:Iiyama North America PLB2403WS 0574281251316,1920x1200@60,0x185,1
                monitor=desc:Dell Inc. DELL U2417H 5K9YD872FY1L,1920x1080@60,1920x0,1,transform,1
                monitor=eDP-1,1920x1080@60,640x1385,1.5
                monitor=,preferred,auto,auto
              '';
            };
          })
        ];
      };
    };
    homeConfigurations = {
      "tux@Monarch" = home-manager.lib.homeManagerConfiguration {
        pkgs = nixpkgs.legacyPackages."aarch64-darwin";
        modules = [
          ({pkgs, ...}: {
            imports = [./home/personal.nix ./home/gui/wezterm.nix];
            home = {
              username = "tux";
              homeDirectory = "/Users/tux";
              stateVersion = "23.05";
              packages = [pkgs.gcc];
            };
            programs = {
              home-manager.enable = true;
              zsh = {
                sessionVariables.CC = "${pkgs.gcc}/bin/gcc";
                envExtra = ''
                  eval "$(/opt/homebrew/bin/brew shellenv)"
                '';
              };
            };
            services.syncthing.enable = true;
          })
        ];
      };
      "xenia@Northstar" = home-manager.lib.homeManagerConfiguration {
        pkgs = nixpkgs.legacyPackages."aarch64-linux";
        modules = [
          {
            imports = [./home/personal.nix];
            home = {
              username = "xenia";
              homeDirectory = "/home/xenia";
              stateVersion = "22.11";
            };
            programs = {
              home-manager.enable = true;
              bash.bashrcExtra = ''
                source $HOME/.nix-profile/etc/profile.d/nix.sh
              '';
            };
            services.syncthing.enable = true;
            fonts.fontconfig.enable = true;
          }
        ];
      };
    };
  };
}