{
  description = "Evie's machine configurations";

  inputs = {
    nixpkgs.url = "github:NixOS/nixpkgs/nixos-unstable";
    home-manager = {
      url = "github:nix-community/home-manager";
      inputs.nixpkgs.follows = "nixpkgs";
    };
    wallpapers.url = "git+https://git.xenia.me.uk/xenia/wallpapers.git";
    neovim-nightly-overlay = {
      url = "github:nix-community/neovim-nightly-overlay";
      inputs.nixpkgs.follows = "nixpkgs";
    };
  };

  outputs = {
    nixpkgs,
    home-manager,
    wallpapers,
    neovim-nightly-overlay,
    ...
  }: let
    home-config = {
      imports = [home-manager.nixosModules.home-manager];
      home-manager = {
        useGlobalPkgs = true;
        useUserPackages = false;
        users.root = {
          imports = [./home/env/bash.nix ./home/env/starship.nix];
          home = {
            username = "root";
            homeDirectory = "/root";
            stateVersion = "22.11";
          };
        };
      };
    };
  in {
    nixosConfigurations = {
      Legion = nixpkgs.lib.nixosSystem {
        pkgs = import nixpkgs {
          system = "x86_64-linux";
          config.allowUnfree = true;
        };
        modules = [
          home-config
          ./hosts/Legion
          ./services/Legion.nix
          {
            home-manager.users.xenia = {
              imports = [./home/personal.nix];
              home = {
                username = "xenia";
                homeDirectory = "/home/xenia";
                stateVersion = "22.11";
              };
            };
          }
        ];
      };
      Vanguard = nixpkgs.lib.nixosSystem {
        pkgs = import nixpkgs {
          system = "x86_64-linux";
          config.allowUnfree = true;
          overlays = [neovim-nightly-overlay.overlay];
        };
        modules = [
          home-config
          ./hosts/Vanguard
          ./desktop/bspwm.nix
          ./desktop/awesome.nix
          ./desktop/qtile.nix
          ./services/sshd
          ./services/syncthing/Vanguard.nix
          ({pkgs, ...}: {
            services.xserver.displayManager = {
              autoLogin.user = "xenia";
              defaultSession = "xfce+bspwm";
            };
            hardware.steam-hardware.enable = true;
            programs = {
              xwayland.enable = true;
              gamescope = {
                enable = true;
                capSysNice = true;
              };
              steam = {
                enable = true;
                remotePlay.openFirewall = true;
                gamescopeSession.enable = true;
              };
            };
            home-manager.users.xenia = {
              imports = [
                ./home/personal.nix
                ./home/desktop/bspwm.nix
                ./home/desktop/awesome
                ./home/gui
              ];
              home = {
                username = "xenia";
                homeDirectory = "/home/xenia";
                stateVersion = "22.11";
              };
              programs.neovim.package = pkgs.neovim-nightly;
              xsession.windowManager.bspwm.extraConfig = ''
                ${pkgs.feh}/bin/feh --no-fehbg --bg-fill ${wallpapers.outputs.default}
              '';
            };
          })
        ];
      };
      Ronin = nixpkgs.lib.nixosSystem {
        pkgs = import nixpkgs {
          system = "x86_64-linux";
          config.allowUnfree = true;
          overlays = [neovim-nightly-overlay.overlay];
        };
        modules = [
          home-config
          ./hosts/Ronin
          ./desktop/bspwm.nix
          ./services/syncthing/Ronin.nix
          ({pkgs, ...}: {
            services.xserver.displayManager = {
              autoLogin.user = "elitherl";
              defaultSession = "xfce+bspwm";
            };
            home-manager.users.elitherl = {
              imports = [
                ./home/work.nix
                ./home/desktop/bspwm.nix
                ./home/gui
              ];
              home = {
                username = "elitherl";
                homeDirectory = "/home/elitherl";
                stateVersion = "22.11";
              };
              programs.neovim.package = pkgs.neovim-nightly;
              xsession.windowManager.bspwm.extraConfig = ''
                if [[ "$(xrandr --query | grep -E '^DP-1-1 connected')" ]]; then
                    xrandr --output eDP-1 --off\
                           --output DP-1-1 --primary --mode 1920x1200 --pos 0x185 --rotate normal\
                           --output DP-1-2 --mode 1920x1080 --pos 1920x0 --rotate left
                    bspc monitor eDP-1 -r
                    bspc monitor DP-1-1 -g 1920x1200+0+185
                    bspc monitor DP-1-2 -g 1080x1920+1920+0
                else
                    xrandr --output eDP-1 --primary --mode 1920x1080 --pos 0x0 --rotate normal\
                           --output DP-1-1 --off\
                           --output DP-1-2 --off
                    bspc monitor eDP-1 -g 1920x1080+0+0
                    bspc monitor DP-1-1 -r
                    bspc monitor DP-1-2 -r
                fi
                for desktop in "main" "dev" "browser" "files" "chat" "remote" "steam" "misc"; do
                    bspc desktop $desktop --to-monitor primary
                done
                bspc monitor primary -o main dev browser files chat remote steam misc
                bspc monitor primary -d main dev browser files chat remote steam misc
                bspc wm -o
                ${pkgs.feh}/bin/feh --no-fehbg --bg-fill ${wallpapers.outputs.default}
              '';
            };
          })
        ];
      };
    };
    homeConfigurations = {
      "tux@Monarch" = home-manager.lib.homeManagerConfiguration {
        pkgs = nixpkgs.legacyPackages."aarch64-darwin";
        modules = [
          ({pkgs, ...}: {
            imports = [./home/personal.nix ./home/gui/wezterm.nix];
            home = {
              username = "tux";
              homeDirectory = "/Users/tux";
              stateVersion = "23.05";
              packages = [pkgs.gcc];
            };
            programs = {
              home-manager.enable = true;
              zsh = {
                sessionVariables.CC = "${pkgs.gcc}/bin/gcc";
                envExtra = ''
                  eval "$(/opt/homebrew/bin/brew shellenv)"
                '';
              };
            };
            services.syncthing.enable = true;
          })
        ];
      };
      "xenia@Northstar" = home-manager.lib.homeManagerConfiguration {
        pkgs = nixpkgs.legacyPackages."aarch64-linux";
        modules = [
          {
            imports = [./home/personal.nix];
            home = {
              username = "xenia";
              homeDirectory = "/home/xenia";
              stateVersion = "22.11";
            };
            programs = {
              home-manager.enable = true;
              bash.bashrcExtra = ''
                source $HOME/.nix-profile/etc/profile.d/nix.sh
              '';
            };
            services.syncthing.enable = true;
            fonts.fontconfig.enable = true;
          }
        ];
      };
    };
  };
}