nixos/home/hyprland/default.nix

{ config, lib, pkgs, hyprland, anyrun, wallpapers, catppuccin-themes, ... }:

{
  imports = [
    hyprland.homeManagerModules.default
    ../alacritty/tiling.nix
    ./waybar/default.nix
    ./swaync/default.nix
    ./rofi/default.nix
    ./anyrun/default.nix
    ./swaylock.nix
    ./gtk.nix
  ];
  home.packages = [ pkgs.libsForQt5.polkit-kde-agent ];
  programs = {
    emacs.package = pkgs.emacs29-pgtk;
    firefox.package = pkgs.firefox-wayland;
    rofi = {
      package = pkgs.rofi-wayland;
      terminal = "${pkgs.alacritty}/bin/alacritty";
      pass.extraConfig = ''
        backend=wtype
        clibpoard_backend=wl-clipboard
      '';
    };
  };
  services.kanshi = {
    enable = true;
    systemdTarget = "hyprland-session.target";
  };
  wayland.windowManager.hyprland = {
    enable = true;
    package = null; # Use package from nixpkgs
    xwayland = {
      enable = true;
      hidpi = true;
    };
    extraConfig = import ./config.nix {
      inherit config pkgs anyrun;
      theme = catppuccin-themes.hyprland;
    };
  };
  xdg.configFile = {
    "hypr/hyprpaper.conf".text = ''
      preload = ${wallpapers.outputs.default}
      wallpaper = ,${wallpapers.outputs.default}
    '';
    "hypr/macchiato.conf".source = ./macchiato.conf;
    "hypr/extra.conf" = lib.mkDefault { text = ""; };
  };
}