nixos/system/Vanguard.nix

{
  config,
  pkgs,
  username,
  ...
}:
{
  imports = [ ./desktop.nix ];
  environment.sessionVariables.MANGOHUD = 1;
  home-manager.users.${username} = {
    home = {
      stateVersion = "23.05";
      packages = with pkgs; [
        krita
        kdenlive
        helvum
        prusa-slicer
        blender
        freecad
        openscad
        kicad-small
        mangohud
        wineWowPackages.waylandFull
        winetricks
        lutris
        cartridges
        prismlauncher
      ];
    };
    programs.obs-studio = {
      enable = true;
      plugins = with pkgs.obs-studio-plugins; [
        wlrobs
        obs-vkcapture
        obs-pipewire-audio-capture
        input-overlay
      ];
    };
    xdg.configFile."MangoHud/MangoHud.conf".text = with config.lib.stylix.scheme; ''
      preset=2
      time
      text_color=${base00}
      gpu_color=${green}
      cpu_color=${green}
      vram_color=${magenta}
      ram_color=${magenta}
      engine_color=${red}
      io_color=${magenta}
      frametime_color=${green}
      background_color=${base05}
      media_player_color=${base00}
      wine_color=${red}
      battery_color=${orange}
      network_color=${red}
    '';
  };
  boot = {
    extraModulePackages = with config.boot.kernelPackages; [ v4l2loopback ];
    extraModprobeConfig = ''
      options v4l2loopback devices=1 video_nr=1 card_label="OBS Cam" exclusive_caps=1
    '';
  };
  hardware = {
    amdgpu = {
      initrd.enable = true;
      opencl.enable = true;
    };
    opengl = {
      enable = true;
      driSupport = true;
      driSupport32Bit = true;
    };
    steam-hardware.enable = true;
  };
  system.stateVersion = "23.05";
  programs = {
    gamemode.enable = true;
    steam = {
      enable = true;
      remotePlay.openFirewall = true;
      gamescopeSession.enable = true;
    };
    gamescope = {
      enable = true;
      capSysNice = true;
    };
  };
  services.ollama = {
    enable = true;
    acceleration = "rocm";
  };
}