{
  description = "";

  nixConfig = {
    extra-substituters = ["https://nix.xenia.me.uk"];
    extra-trusted-public-keys = ["nix.xenia.me.uk:tlgwOaG5KMLjQUk2YaErS8mAG69ZCr3PaHXZYi+Y5eI="];
  };

  inputs = {
    nixpkgs.url = "github:nixos/nixpkgs/nixos-23.11";
    home-manager = {
      url = "github:nix-community/home-manager/release-23.11";
      inputs.nixpkgs.follows = "nixpkgs";
    };
    iosevka-custom.url = "git+https://git.xenia.me.uk/pixelifytica/iosevka.git";
    base16.url = "github:SenchoPens/base16.nix";
    tt-schemes = {
      url = "github:tinted-theming/schemes";
      flake = false;
    };
  };

  outputs = {
    nixpkgs,
    home-manager,
    iosevka-custom,
    base16,
    tt-schemes,
    ...
  }: let
    pkgs = import nixpkgs {system = "x86_64-linux";};
    extraSpecialArgs = {
      inherit tt-schemes;
      accentColour = "base07"; # catppuccin lavender
      catppuccinVariant = "Mocha";
      fonts = with pkgs;
      with iosevka-custom.outputs; rec {
        sizes = {
          applications = 12;
          desktop = 10;
          popups = 14;
          terminal = 12;
        };
        serif = sansSerif;
        sansSerif = {
          name = names."iosevka-custom-aile";
          package = packages.${system}."iosevka-custom-aile";
        };
        monospace = {
          name = names."iosevka-custom-nerdfont";
          package = packages.${system}."iosevka-custom-nerdfont";
        };
        emoji = {
          name = "Noto Color Emoji";
          package = noto-fonts-emoji;
        };
      };
    };
  in {
    inherit (home-manager) defaultPackage;
    homeConfigurations = {
      "pixelifytica" = home-manager.lib.homeManagerConfiguration {
        inherit pkgs extraSpecialArgs;
        modules = [
          base16.homeManagerModule
          ./home.nix
        ];
      };
    };
  };
}