home-manager/programs/desktop/plasma6/default.nix

{
  pkgs,
  fonts,
  ...
}: {
  home.packages = with pkgs; [
    fonts.serif.package
    fonts.sansSerif.package
    fonts.monospace.package
    volantes-cursors
    (papirus-icon-theme.override {color = "violet";})
  ];
  services.gpg-agent.pinentryPackage = pkgs.pinentry-qt;
  programs.plasma = {
    enable = true;
    overrideConfig = true;

    workspace = {
      clickItemTo = "open";
      lookAndFeel = "org.kde.breeze.desktop";
      cursor = {
        theme = "volantes_cursors";
        size = 32;
      };
      iconTheme = "Papirus";
      wallpaper = "${../wallpapers/landscapes/tropic_island_day.jpg}";
    };

    fonts = let
      general = {
        family = fonts.sansSerif.name;
        pointSize = 10;
      };
      fixedWidth = {
        family = fonts.monospace.name;
        pointSize = 10;
      };
    in {
      inherit general fixedWidth;
      menu = general;
      toolbar = general;
      windowTitle = general;
      small = {
        inherit (general) family;
        pointSize = general.pointSize - 2;
      };
    };

    hotkeys.commands = {
      "launch-terminal" = {
        name = "Launch Alacritty Terminal Emulator";
        key = "Meta+Alt+T";
        command = "alacritty";
      };
      "launch-emacs" = {
        name = "Launch Emacs Client Window";
        key = "Meta+Alt+E";
        command = "emacsclient -c";
      };
    };

    panels = [
      {
        height = 44;
        lengthMode = "fill";
        location = "left";
        alignment = "center";
        hiding = "none";
        floating = true;
        widgets = [
          {
            name = "org.kde.plasma.kickoff";
            config = {General.icon = "nix-snowflake-white";};
          }
          "org.kde.plasma.pager"
          {
            name = "org.kde.plasma.icontasks";
            config = {
              General.launchers = [
                "applications:org.kde.dolphin.desktop"
                "applications:Alacritty.desktop"
                "applications:emacs.desktop"
                "applications:firefox.desktop"
                "applications:org.kde.elisa.desktop"
              ];
            };
          }
          "org.kde.plasma.systemtray"
          {
            digitalClock = {
              date.format = {custom = "d/MM";};
              time.format = "24h";
              calendar.showWeekNumbers = true;
            };
          }
          "org.kde.plasma.showdesktop"
        ];
      }
    ];

    shortcuts = {
      ksmserver = {
        "Lock Session" = ["Screensaver" "Meta+Alt+L"];
      };
    };

    kwin.effects = {
      translucency.enable = true;
      blur.enable = true;
      cube.enable = true;
    };

    configFile = {
      kscreenlockerrc = {
        Greeter.WallpaperPlugin = "org.kde.potd";
      };
    };
  };
}